Air应用：SQLite操作

2018-12-18 zhulinan Flash
Flash的Air项目中是否可以使用SQLite，如何操作？请看样例源码：
package {
	import flash.events.*;
	import flash.display.MovieClip;
	import flash.data.SQLConnection;
	import flash.data.SQLStatement;
	import flash.data.SQLResult;
	import flash.filesystem.File;

	public class Main extends MovieClip {
		private var _conn:SQLConnection = new SQLConnection();

		public function Main() {
			addEventListener(Event.ADDED_TO_STAGE, addedHandler);
		}
		private function addedHandler(e:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, addedHandler);

			_conn.addEventListener(SQLEvent.OPEN, openResult);
			_conn.addEventListener(SQLErrorEvent.ERROR, openError);

			var folder:File = File.applicationStorageDirectory; //Windows下位置：C:\Users\用户名\AppData\Roaming\app ID\Local Store\
			var dbFile:File = folder.resolvePath("DBSample.db");
			_conn.open(dbFile);

			addEventListener(Event.REMOVED_FROM_STAGE, removedHandler);
		}
		private function openError(e:SQLErrorEvent):void {
			var str:String = "";
			if (e.error.errorID == 3138) {
				str = "Incorrect encryption key\n"; //加密的数据库密码错误
			} else {
				str = "Error message:" + e.error.message + "\nDetails:" + e.error.details + "\n";
			}
			trace(str);
		}
		private function openResult(e:SQLEvent):void {
			trace("连接数据库成功");
			e.target.removeEventListener(SQLErrorEvent.ERROR, openError);
			e.target.removeEventListener(SQLEvent.OPEN, openResult);

			btn1.addEventListener(MouseEvent.CLICK, btn1ClickHandler);
			btn2.addEventListener(MouseEvent.CLICK, btn2ClickHandler);
		}

		private function btn1ClickHandler(e:MouseEvent):void {
			var stmt:SQLStatement = new SQLStatement();
			stmt.sqlConnection = _conn;
			stmt.addEventListener(SQLErrorEvent.ERROR, createError);
			stmt.addEventListener(SQLEvent.RESULT, createResult);
			stmt.text = "CREATE TABLE IF NOT EXISTS [user] ([id] integer PRIMARY KEY AUTOINCREMENT, [name] VARCHAR(50) NOT NULL ,`age` INT(11) NOT NULL);"
			stmt.execute();
		}

		private function createError(e:SQLErrorEvent):void {
			trace("Error message:", e.error.message);
			trace("Details:", e.error.details);
		}
		private function createResult(e:SQLEvent):void {
			trace("数据库生成表成功");
			e.target.removeEventListener(SQLEvent.RESULT, createResult);
			e.target.removeEventListener(SQLErrorEvent.ERROR, createError);

			var stmt:SQLStatement = new SQLStatement();
			stmt.sqlConnection = _conn;
			stmt.addEventListener(SQLErrorEvent.ERROR, insertError);
			stmt.addEventListener(SQLEvent.RESULT, insertResult);

			stmt.text = "INSERT INTO `user` (name, age) VALUES (@name, @age)";
			stmt.parameters["@name"] = "elight";
			stmt.parameters["@age"] = 18;
			stmt.execute();
		}
		private function insertError(event:SQLErrorEvent):void { 
			trace("Error message:", event.error.message);
			trace("Details:", event.error.details);
		} 
		private function insertResult(e:SQLEvent):void {
			trace("写数据成功");
			e.target.removeEventListener(SQLErrorEvent.ERROR, insertError);
			e.target.removeEventListener(SQLEvent.RESULT, insertResult);
		}

		private function btn2ClickHandler(e:MouseEvent):void {
			var stmt:SQLStatement = new SQLStatement();
			stmt.sqlConnection = _conn;
			stmt.addEventListener(SQLErrorEvent.ERROR, selectError);
			stmt.addEventListener(SQLEvent.RESULT, selectResult);
			stmt.text = "SELECT id, name, age FROM user";
			stmt.execute();
		}
		private function selectResult(e:SQLEvent):void {
			var result:SQLResult = e.target.getResult();
			var numResults:int = result.data.length;
			var output:String = "";
			for (var i:int = 0; i < numResults; i++) {
				var row:Object = result.data[i];
				output += "Id: " + row.id;
				output += "; Name: " + row.name;
				output += "; Age: " + row.age + "\n";
			}
			txtTs.text = output;
		} 
		private function selectError(event:SQLErrorEvent):void {
			// Information about the error is available in the
			// event.error property, which is an instance of
			// the SQLError class.
		}
		private function removedHandler(e:Event):void {
			trace("Dd234Connect is removed");
		}
	}
}
参考资料：在 AIR 中使用本地 SQL 数据库
本例下载：SQLite数据库.zip
分享到： QQ空间新浪微博腾讯微博微信更多
« iOS iPhone X 适配 | 设计资源»
Air应用：SQLite操作

日历

存档

最新评论

链接

搜索
